100 PRINT"[147]            ARMBRUSTSCHIESSEN"
105 GETA$:IFA$=""GOTO105
110 DIMZ(37),F(37),Z1(37),F1(37):POKE650,64:POKE53281,15:POKE53280,2
115 A$(0)=" [213][219][201][157][157][157]":TM$(1)="000000":TM$(2)="000000"
120 A$(1)="   [157][157][157][157][213][219][201] [157][157][157][157]"
125 BI(0)=32:BI(1)=42:SF(0)=15:SF(1)=5:SS(1)=66:SS(0)=32
130 SI=54272:FL=SI:FH=SI+1:TL=SI+2:TH=SI+3:W=SI+4:A=SI+5:H=SI+6:L=SI+24
135 PRINT"[147]WIEVIELE SPIELER ( 1 ODER 2 ) ?";
140 GETSW$:IFSW$=""THEN140
145 SW=VAL(SW$):IFSW<1ORSW>2THEN140
150 IFSW=1THENPRINT"  EINER"
155 IFSW=2THENPRINT"  ZWEI"
160 GOSUB390:GOSUB510
165 GOSUB485
170 FORRD=1TO3:PRINT"AUGENBLICK BITTE !":GOSUB220
175 FORSP=1TOSW:P=0:K=1
180 GOSUB470:GOSUB600:TI$=TM$(SP):GOSUB270:TM$(SP)=TI$
185 GOSUB485
190 PRINT"WEITER >RETURN< ?"
195 GETW$:IFW$><CHR$(13)THEN195
200 PRINT"[147]";:NEXT
205 NEXT
210 GOTO640
215 :
220 FORX=1TO36:Z1(X)=1:F1(X)=1:NEXT
225 FORX=1TO10
230 Y=INT(RND(1)*36+1):IFZ1(Y)=0THEN230
235 Z1(Y)=0:NEXT
240 FORX=1TO36:IFZ1(X)=0THEN265
245 Y=INT(RND(1)*15+1)
250 IFY=2ORY=4ORY=6ORY=8ORY=9ORY=10ORY=14THEN260
255 GOTO245
260 F1(X)=Y
265 NEXT:RETURN
270 FORX=1TO19:PRINT:NEXT
275 K=ABS(K-1):IFK=0THENAA=1:BB=36:CC=1
280 IFK=1THENAA=36:BB=1:CC=-1
285 :
290 FORX=AATOBBSTEPCC:PRINT""A$(K);
295 FORY=1TOG:NEXT
300 GETX$:IFX$=""THEN315
305 GOSUB325
310 IFP=26THENRETURN
315 NEXT:PRINTTAB(X)A$(ABS(K-1));
320 GOTO275
325 REM....SCHUSS
330 SI=54272:POKESI+24,15
335 POKESI,200:POKESI+1,90
340 POKESI+5,96:POKESI+4,17
345 :
350 PRINT"[196][157][145][144]^";:PU=PEEK(211):SU=SU+1
355 FORI=1TO17:PRINT"[157] [157][145]^";:FORY=1TO5:NEXT:POKESI+1,90+Y:NEXT:PRINT"[157] ";
360 POKESI+4,0:GOSUB430
365 POKE198,0:PRINT""
370 PRINT"[144]"TAB(17);RD;TAB(23);SU;TAB(30)"    [157][157][157][157]"PT
375 PRINT"";:FORI=1TO19:PRINT:NEXT:PRINTTAB(X+K-1)A$(K);
380 :
385 RETURN
390 SI=54272:POKESI+24,15
395 POKESI,200:POKESI+1,60
400 POKESI+5,5:POKESI+6,0:POKESI+4,17
405 FORY=1TO200:NEXT
410 FORY=1TO100:NEXT
415 POKESI,200:POKESI+1,50
420 POKESI+5,6:POKESI+6,0:POKESI+4,17
425 POKESI+4,0:RETURN
430 REM.....PUNKTE RECHNEN
435 IFZ(PU-2)=1THEN450
440 PT=PT-10
445 RETURN
450 IFPU-2>34ORPU-2<3THENPT=PT+100:GOTO460
455 PT=PT+20
460 P=P+1:Z(PU-2)=0:GOSUB390
465 RETURN
470 REM BLUMEN PRO SPIELER
475 FORX=1TO36:Z(X)=Z1(X):F(X)=F1(X):NEXT
480 RETURN
485 REMZAEHLER FUER SPIELER 1 + 2
490 SU(SP)=SU(SP)+SU:SU=0
495 PT(SP)=PT(SP)+PT:PT=0
500 :
505 RETURN
510 REM WAGL DER GESCHWINDIGKEIT
515 PRINT"   ";:IFSW=1THENPRINT"[144]WILLST DU";
520 IFSW=2THENPRINT"[144]WOLLT IHR";
525 PRINTTAB(15)"S[146]CHNELL"
530 PRINTTAB(15)"N[146]ORMAL"
535 PRINTTAB(15)"L[146]ANGSAM     [144]SPIELEN ?"
540 PRINT""TAB(7)"ANFANGSBUCHSTABEN EINGEBEN. ";
545 GETG$:IFG$=""THEN545
550 IFG$="S"THENG=0:PRINT"S"
555 IFG$="N"THENG=50:PRINT"N"
560 IFG$="L"THENG=100:PRINT"L"
565 IFG$="L"ORG$="N"ORG$="S"THEN575
570 GOTO545
575 PRINT"[144]  VORNAME EINGEBEN U. >RETURN< DRUECKEN":FORN=1TOSW
580 PRINT"  VORNAME VON SPIELER";N;:INPUTN$(N)
585 IFLEN(N$(N))<3THENPRINT"[144]NAME ZU KURZ[145][145]":GOTO580
590 IFLEN(N$(N))>11THENPRINT"[144]NAME ZU LANG[145][145]":GOTO580
595 NEXT:RETURN
600 REM BLUMEN SETZEN
605 PRINT"[147]";:FORX=1TO36:POKE55337+X,F(X):POKE1065+X,BI(Z(X))
610 POKE55377+X,SF(Z(X)):POKE1105+X,SS(Z(X))
615 NEXT
620 FORX=1TO21:PRINT:NEXT:PRINT" SPIELER[146]        RUNDE[146] SCHUSS[146] PUNKTE[146]"
625 PRINT"[144] "N$(SP);TAB(17);RD;TAB(23);SU;TAB(30)"    [157][157][157][157]"PT
630 PRINT"";
635 RETURN
640 PRINT"[147]       E R G E B N I S S E "
645 PRINT""TAB(19-LEN(N$(1)))N$(1);:IFSW=2THENPRINTTAB(34-LEN(N$(2)))N$(2);
650 PT$(1)=STR$(PT(1)):PT$(2)=STR$(PT(2))
655 PRINT"":PRINT"  PUNKTE"TAB(19-LEN(PT$(1)))PT$(1);
660 IFSW=2THENPRINTTAB(34-LEN(PT$(2)))PT$(2);
665 SU$(1)=STR$(SU(1)):SU$(2)=STR$(SU(2))
670 PRINT:PRINT"  SCHUSS"TAB(19-LEN(SU$(1)))SU$(1);
675 IFSW=2THENPRINTTAB(34-LEN(SU$(2)))SU$(2);
680 PRINT:PRINT"  ZEIT "TAB(10)VAL(MID$(TM$(1),3,2))"MIN";
685 PRINTVAL(RIGHT$(TM$(1),2))"SEK";
690 IFSW<2THENPRINT:GOTO700
695 PRINTTAB(26)VAL(MID$(TM$(2),3,2))"MIN"VAL(RIGHT$(TM$(2),2))"SEK"
700 IFSW=1THEN740
705 SG=1:IFPT(2)>PT(1)THENSG=2
710 IFPT(1)=PT(2)ANDSU(2)<SU(1)THENSG=2
715 TT(1)=VAL(MID$(TM$(1),3,2))*60+VAL(RIGHT$(TM$(1),2))
720 TT(2)=VAL(MID$(TM$(2),3,2))*60+VAL(RIGHT$(TM$(2),2))
725 IFPT(1)=PT(2)ANDSU(2)=SU(1)ANDTT(2)<TT(1)THENSG=2
730 PRINT"  "N$(SG)" IST SIEGER."
735 :
740 PRINT"    NOCH EIN SPIEL (J/N) ?"
745 GETA$:IFA$=""THEN745
750 IFA$="J"THENRUN
755 IFA$="N"THEN765
760 GOTO745
765 PRINT"[147]VIELEN DANK FUERS SPIEL"
770 IF SW=1THENPRINT"DU WARST WIEDER ";
775 IFSW=2THENPRINT"IHR WART WIEDER ";
780 N=INT(RND(X)*6+1)
785 NM$(1)="SUPER":NM$(2)="KLASSE":NM$(3)="EINE WUCHT"
790 NM$(4)="SCHNUCKELIG":NM$(5)="BOMBIG":NM$(6)="GANZ HERVORRAGEND"
795 PRINTNM$(N):FORA=1TO5000:NEXT
800 GETA$:IFA$=""THENGOTO800
805 POKE631,19:POKE632,13:POKE633,13:POKE198,3:POKE650,0:END